// Insurgency's M60
/* Model Credits
/ Model: Twinke Masta, Firearms Source team (Bag)
/ Textures: Millenia, Firearms Source team (Bag)
/ Animations: MyZombieKillerz
/ Sounds: Spycer42, D.N.I.O. 071 (Conversion to .ogg format)
/ Sprites: D.N.I.O. 071 (Model Render), R4to0 (Vector), KernCore (.spr Compile)
/ Misc: Norman The Loli Pirate (UV Chop, World Model, World Model UVs), D.N.I.O. 071 (World Model UVs, Compile), KernCore (World Model UVs)
/ Script: KernCore
*/

#include "../base"

namespace INS2_M60
{

// Animations
enum INS2_M60_Animations
{
	IDLE = 0,
	DRAW_FIRST,
	DRAW,
	HOLSTER,
	FIRE,
	DRYFIRE,
	RELOAD,
	RELOAD_HALF,
	RELOAD_EMPTY,
	IRON_IDLE,
	IRON_FIRE,
	IRON_DRYFIRE,
	IRON_TO,
	IRON_FROM,
	BIPOD_IN,
	BIPOD_OUT,
	BIPOD_IDLE,
	BIPOD_FIRE,
	BIPOD_DRYFIRE,
	BIPOD_RELOAD,
	BIPOD_RELOAD_HALF,
	BIPOD_RELOAD_EMPTY,
	BIPOD_IRON_IDLE,
	BIPOD_IRON_FIRE,
	BIPOD_IRON_DRYFIRE,
	BIPOD_IRON_TO,
	BIPOD_IRON_FROM,
	BIPOD_IRON_IN,
	BIPOD_IRON_OUT
};

enum M60_Bodygroups
{
	ARMS = 0,
	M60_STUDIO0,
	M60_STUDIO1,
	M60_STUDIO2,
	MAIN_BULLETS,
	HELPER_BULLETS
};

// Models
string W_MODEL = "models/ins2/wpn/m60/w_m60.mdl";
string V_MODEL = "models/ins2/wpn2/m60/v_m60_v2.mdl";
string P_MODEL = "models/ins2/wpn/m60/p_m60.mdl";
string A_MODEL = "models/ins2/ammo/mags.mdl";
int MAG_BDYGRP = 47;
// Sprites
string SPR_CAT = "ins2/lmg/"; //Weapon category used to get the sprite's location
// Sounds
string SHOOT_S = "ins2/wpn/m60/shoot.ogg";
string EMPTY_S = "ins2/wpn/m60/empty.ogg";
// Information
int MAX_CARRY   	= 600;
int MAX_CLIP    	= 200;
int DEFAULT_GIVE 	= MAX_CLIP * 3;
int WEIGHT      	= 55;
int FLAGS       	= ITEM_FLAG_NOAUTORELOAD | ITEM_FLAG_NOAUTOSWITCHEMPTY | ITEM_FLAG_ESSENTIAL;
uint DAMAGE     	= 30;
uint SLOT       	= 7;
uint POSITION   	= 13;
float RPM_AIR   	= 600; //Rounds per minute in air
float RPM_WTR   	= 500; //Rounds per minute in water
string AMMO_TYPE 	= "ins2_7.62x51mm";

class weapon_ins2m60 : ScriptBasePlayerWeaponEntity, INS2BASE::WeaponBase, INS2BASE::BipodWeaponBase
{
	private CBasePlayer@ m_pPlayer
	{
		get const	{ return cast<CBasePlayer@>( self.m_hPlayer.GetEntity() ); }
		set       	{ self.m_hPlayer = EHandle( @value ); }
	}
	private int m_iShell;
	private bool m_WasDrawn, m_bInReload;
	private int GetBodygroup()
	{
		if( self.m_iClip >= 9 )
			m_iCurBodyConfig = g_ModelFuncs.SetBodygroup( g_ModelFuncs.ModelIndex( V_MODEL ), m_iCurBodyConfig, MAIN_BULLETS, 8 );
		else if( self.m_iClip <= 1 )
			m_iCurBodyConfig = g_ModelFuncs.SetBodygroup( g_ModelFuncs.ModelIndex( V_MODEL ), m_iCurBodyConfig, MAIN_BULLETS, 0 );
		else
			m_iCurBodyConfig = g_ModelFuncs.SetBodygroup( g_ModelFuncs.ModelIndex( V_MODEL ), m_iCurBodyConfig, MAIN_BULLETS, self.m_iClip - 1 );

		return m_iCurBodyConfig;
	}
	private int SetBodygroup()
	{
		if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) > 0 )
		{
			if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) >= 9 || (m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) + self.m_iClip) >= 9 )
				m_iCurBodyConfig = g_ModelFuncs.SetBodygroup( g_ModelFuncs.ModelIndex( V_MODEL ), m_iCurBodyConfig, HELPER_BULLETS, 8 );
			else if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) < 9 && (m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) + self.m_iClip) < 9 )
				m_iCurBodyConfig = g_ModelFuncs.SetBodygroup( g_ModelFuncs.ModelIndex( V_MODEL ), m_iCurBodyConfig, HELPER_BULLETS, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) + (self.m_iClip - 1) );
		}

		return m_iCurBodyConfig;
	}
	private array<string> Sounds = {
		"ins2/wpn/m60/bdply.ogg",
		"ins2/wpn/m60/brtrct.ogg",
		"ins2/wpn/m60/bltbk.ogg",
		"ins2/wpn/m60/bltrel.ogg",
		"ins2/wpn/m60/close.ogg",
		"ins2/wpn/m60/open.ogg",
		"ins2/wpn/m60/hit.ogg",
		"ins2/wpn/m60/magin.ogg",
		"ins2/wpn/m60/magemp.ogg",
		"ins2/wpn/m60/magout.ogg",
		"ins2/wpn/m60/throw.ogg",
		"ins2/wpn/uni/align.ogg",
		"ins2/wpn/uni/jingle.ogg",
		SHOOT_S,
		EMPTY_S
	};

	void Spawn()
	{
		Precache();
		m_WasDrawn = false;
		m_bInReload = false;
		WeaponBipodMode = INS2BASE::BIPOD_UNDEPLOYED;
		CommonSpawn( W_MODEL, DEFAULT_GIVE );
	}

	void Precache()
	{
		self.PrecacheCustomModels();
		g_Game.PrecacheModel( W_MODEL );
		g_Game.PrecacheModel( V_MODEL );
		g_Game.PrecacheModel( P_MODEL );
		g_Game.PrecacheModel( A_MODEL );
		m_iShell = g_Game.PrecacheModel( INS2BASE::BULLET_762x51 );

		//g_Game.PrecacheOther( GetAmmoName() );

		INS2BASE::PrecacheSound( Sounds );
		INS2BASE::PrecacheSound( INS2BASE::DeployFirearmSounds );
		
		g_Game.PrecacheGeneric( "sprites/" + SPR_CAT + self.pev.classname + ".txt" );
		g_Game.PrecacheGeneric( "events/" + "muzzle_ins2_MGs_big.txt" );
		CommonPrecache();
	}

	bool GetItemInfo( ItemInfo& out info )
	{
		info.iMaxAmmo1 	= MAX_CARRY; //(INS2BASE::ShouldUseCustomAmmo) ? MAX_CARRY : INS2BASE::DF_MAX_CARRY_556;
		info.iAmmo1Drop	= MAX_CLIP;
		info.iMaxAmmo2 	= -1;
		info.iAmmo2Drop	= -1;
		info.iMaxClip 	= MAX_CLIP;
		info.iSlot  	= SLOT;
		info.iPosition 	= POSITION;
		info.iId     	= g_ItemRegistry.GetIdForName( self.pev.classname );
		info.iFlags 	= FLAGS;
		info.iWeight 	= WEIGHT;

		return true;
	}

	bool AddToPlayer( CBasePlayer@ pPlayer )
	{
		return CommonAddToPlayer( pPlayer );
	}

	bool PlayEmptySound()
	{
		return CommonPlayEmptySound( EMPTY_S );
	}

	bool Deploy()
	{
		PlayDeploySound( 3 );
		m_bInReload = false;

		m_pPlayer.SetMaxSpeedOverride( -1 );

		SetThink( ThinkFunction( ShowBipodSpriteThink ) );
		self.pev.nextthink = g_Engine.time + 0.2;

		//if( m_WasDrawn == false )
		//{
		//	m_WasDrawn = true;
		//	return Deploy( V_MODEL, P_MODEL, DRAW_FIRST, "saw", GetBodygroup(), (89.0/30.0) );
		//}
		//else
			return Deploy( V_MODEL, P_MODEL, DRAW, "saw", GetBodygroup(), (58.0/55.0) );
	}

	void Holster( int skipLocal = 0 )
	{
		m_bInReload = false;
		WeaponBipodMode = INS2BASE::BIPOD_UNDEPLOYED;
		m_pPlayer.SetMaxSpeedOverride( -1 );
		CommonHolster();

		BaseClass.Holster( skipLocal );
	}

	void ShootEmpty()
	{
		self.PlayEmptySound();
		if( WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED )
			self.SendWeaponAnim( (WeaponADSMode == INS2BASE::IRON_IN) ? IRON_DRYFIRE : DRYFIRE, 0, GetBodygroup() );
		else if( WeaponBipodMode == INS2BASE::BIPOD_DEPLOYED )
			self.SendWeaponAnim( (WeaponADSMode == INS2BASE::IRON_IN) ? BIPOD_IRON_DRYFIRE : BIPOD_DRYFIRE, 0, GetBodygroup() );

		self.m_flNextPrimaryAttack = WeaponTimeBase() + 0.3f;
	}

	void PrimaryAttack()
	{
		if( IsWeaponEmpty() )
		{
			ShootEmpty();
			return;
		}
		else if( IsNoclipWeaponEmpty() )
		{
			ShootEmpty();
			return;
		}

		self.m_flNextPrimaryAttack = self.m_flNextSecondaryAttack = (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? WeaponTimeBase() + GetFireRate( RPM_WTR ) : WeaponTimeBase() + GetFireRate( RPM_AIR );
		self.m_flTimeWeaponIdle = WeaponTimeBase() + 1.5f;

		m_pPlayer.m_iWeaponVolume = LOUD_GUN_VOLUME;
		m_pPlayer.m_iWeaponFlash = BRIGHT_GUN_FLASH;

		if( WeaponADSMode != INS2BASE::IRON_IN && WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED )
		{
			if( !( m_pPlayer.pev.flags & FL_ONGROUND != 0 ) )
			{
				ShootWeapon( SHOOT_S, 1, VECTOR_CONE_10DEGREES, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
				//KickBack( 0.95, 0.325, 0.25, 0.025, 4.5, 2.5, 9 );
				//m_pPlayer.pev.punchangle.x -= 1.5;
			}
			else if( m_pPlayer.pev.velocity.Length2D() > 150 )
			{
				ShootWeapon( SHOOT_S, 1, VECTOR_CONE_7DEGREES, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
				//KickBack( 0.95, 0.325, 0.25, 0.025, 4.5, 2.5, 9 );
				//m_pPlayer.pev.punchangle.x -= 1.5;
			}
			else if( m_pPlayer.pev.flags & FL_DUCKING != 0 )
			{
				ShootWeapon( SHOOT_S, 1, VECTOR_CONE_4DEGREES, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
				//KickBack( 0.95, 0.325, 0.25, 0.025, 4.5, 2.5, 9 );
				//m_pPlayer.pev.punchangle.x -= 1.5;
			}
			else
			{
				ShootWeapon( SHOOT_S, 1, VECTOR_CONE_5DEGREES, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
				//KickBack( 0.95, 0.325, 0.25, 0.025, 4.5, 2.5, 9 );
				//m_pPlayer.pev.punchangle.x -= 1.5;
			}

			m_pPlayer.pev.punchangle.x = Math.RandomFloat( -2.0, 1.0 );
			m_pPlayer.pev.punchangle.y += Math.RandomFloat( -0.3, 0.3 );
		}
		else if( WeaponBipodMode == INS2BASE::BIPOD_DEPLOYED )
		{
			ShootWeapon( SHOOT_S, 1, VECTOR_CONE_SNIPER_ACCURACY, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
			m_pPlayer.pev.punchangle.x = -1.5;
			m_pPlayer.pev.punchangle.y += Math.RandomFloat( -0.3, 0.3 );
			//PunchAngle( Vector( Math.RandomFloat( -1.875, -2.475 ), (Math.RandomLong( 0, 1 ) < 0.5) ? -0.6f : 0.9f, Math.RandomFloat( -0.5, 0.5 ) ) );
		}
		else if( WeaponBipodMode == INS2BASE::BIPOD_DEPLOYED && WeaponADSMode != INS2BASE::IRON_IN)
		{
			ShootWeapon( SHOOT_S, 1, VECTOR_CONE_3DEGREES, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
			m_pPlayer.pev.punchangle.x = -1.0;
			m_pPlayer.pev.punchangle.y += Math.RandomFloat( -0.3, 0.3 );
			//PunchAngle( Vector( Math.RandomFloat( -1.875, -2.475 ), (Math.RandomLong( 0, 1 ) < 0.5) ? -0.6f : 0.9f, Math.RandomFloat( -0.5, 0.5 ) ) );
		}
		else
		{
			ShootWeapon( SHOOT_S, 1, VECTOR_CONE_SNIPER_ACCURACY, (m_pPlayer.pev.waterlevel == WATERLEVEL_HEAD) ? 1024 : 8192, DAMAGE, true, DMG_BULLET | DMG_NEVERGIB );
			m_pPlayer.pev.punchangle.x = -1.0;
			m_pPlayer.pev.punchangle.y += Math.RandomFloat( -0.3, 0.3 );
			//PunchAngle( Vector( Math.RandomFloat( -1.875, -2.475 ), (Math.RandomLong( 0, 1 ) < 0.5) ? -0.6f : 0.9f, Math.RandomFloat( -0.5, 0.5 ) ) );
		}

		if( WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED )
		{
			if( WeaponADSMode == INS2BASE::IRON_IN )
				self.SendWeaponAnim( IRON_FIRE, 0, GetBodygroup() );
			else
				self.SendWeaponAnim( FIRE, 0, GetBodygroup() );
		}
		else if( WeaponBipodMode == INS2BASE::BIPOD_DEPLOYED )
		{
			if( WeaponADSMode == INS2BASE::IRON_IN )
				self.SendWeaponAnim( BIPOD_IRON_FIRE, 0, GetBodygroup() );
			else
				self.SendWeaponAnim( BIPOD_FIRE, 0, GetBodygroup() );
		}

		ShellEject( m_pPlayer, m_iShell, (WeaponADSMode != INS2BASE::IRON_IN) ? Vector( 14, 5.5, -9 ) : Vector( 15, 2, -4.5 ) );
	}

	void SecondaryAttack()
	{
		self.m_flTimeWeaponIdle = self.m_flNextSecondaryAttack = WeaponTimeBase() + 0.2;
		self.m_flNextPrimaryAttack = WeaponTimeBase() + 0.13;
		
		switch( WeaponADSMode )
		{
			case INS2BASE::IRON_OUT:
			{
				self.SendWeaponAnim( (WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED) ? IRON_TO : BIPOD_IRON_TO, 0, GetBodygroup() );
				EffectsFOVON( 40 );
				break;
			}
			case INS2BASE::IRON_IN:
			{
				self.SendWeaponAnim( (WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED) ? IRON_FROM : BIPOD_IRON_FROM, 0, GetBodygroup() );
				EffectsFOVOFF();
				break;
			}
		}
	}

	void TertiaryAttack()
	{
		if( WeaponADSMode == INS2BASE::IRON_IN )
			DeployBipod( BIPOD_IRON_IN, BIPOD_IRON_OUT, GetBodygroup(), (45.0/30.0), (58.0/30.0) );
		else
			DeployBipod( BIPOD_IN, BIPOD_OUT, GetBodygroup(), (45.0/30.0), (58.0/30.0) );
			//m_pPlayer.SetMaxSpeedOverride( -1 );
	}

	void ItemPostFrame()
	{
		BaseClass.ItemPostFrame();
	}

	void ItemPreFrame()
	{
		if( m_reloadTimer < g_Engine.time && canReload )
			self.Reload();

		if( m_bInReload )
			m_bInReload = false;

		BaseClass.ItemPreFrame();
	}

	void Reload()
	{
		if( self.m_iClip == MAX_CLIP || m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 0 )
			return;

		if( WeaponADSMode == INS2BASE::IRON_IN )
		{
			self.SendWeaponAnim( (WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED) ? IRON_FROM : BIPOD_IRON_FROM, 0, GetBodygroup() );
			m_reloadTimer = g_Engine.time + 0.16;
			m_pPlayer.m_flNextAttack = 0.16;
			canReload = true;
			EffectsFOVOFF();
		}

		if( m_reloadTimer < g_Engine.time )
		{
			m_bInReload = true;
			if( WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED )
			{
				if( self.m_iClip > 0 && self.m_iClip < 9 )
					Reload( MAX_CLIP, RELOAD_HALF, (114.0/12.07/2), SetBodygroup() );
				else if( self.m_iClip == 0 )
					Reload( MAX_CLIP, RELOAD_EMPTY, (123.0/12.03/2), SetBodygroup() );
				else
					Reload( MAX_CLIP, RELOAD, (156.0/18.0/2), SetBodygroup() );
			}
			else if( WeaponBipodMode == INS2BASE::BIPOD_DEPLOYED )
			{
				if( self.m_iClip > 0 && self.m_iClip < 9 )
					Reload( MAX_CLIP, BIPOD_RELOAD_HALF, (113.0/12.07/2), SetBodygroup() );
				else if( self.m_iClip == 0 )
					Reload( MAX_CLIP, BIPOD_RELOAD_EMPTY, (123.0/12.03/2), SetBodygroup() );
				else
					Reload( MAX_CLIP, BIPOD_RELOAD, (154.0/18.0/2), SetBodygroup() );
			}
			canReload = false;
		}

		BaseClass.Reload();
	}

	void WeaponIdle()
	{
		if( self.m_flNextPrimaryAttack < g_Engine.time )
			m_iShotsFired = 0;

		self.ResetEmptySound();
		m_pPlayer.GetAutoaimVector( AUTOAIM_10DEGREES );

		if( self.m_flTimeWeaponIdle > WeaponTimeBase() )
			return;

		if( WeaponBipodMode == INS2BASE::BIPOD_UNDEPLOYED )
		{
			self.SendWeaponAnim( (WeaponADSMode == INS2BASE::IRON_IN) ? IRON_IDLE : IDLE, 0, GetBodygroup() );
		}
		else if( WeaponBipodMode == INS2BASE::BIPOD_DEPLOYED )
		{
			self.SendWeaponAnim( (WeaponADSMode == INS2BASE::IRON_IN) ? BIPOD_IRON_IDLE : BIPOD_IDLE, 0, GetBodygroup() );
		}

		self.m_flTimeWeaponIdle = WeaponTimeBase() + g_PlayerFuncs.SharedRandomFloat( m_pPlayer.random_seed, 5, 7 );
	}
}

/*class M60_MAG : ScriptBasePlayerAmmoEntity, INS2BASE::AmmoBase
{
	void Spawn()
	{
		Precache();
		g_EntityFuncs.SetModel( self, A_MODEL );
		self.pev.body = MAG_BDYGRP;
		BaseClass.Spawn();
	}
	
	void Precache()
	{
		g_Game.PrecacheModel( A_MODEL );
		CommonPrecache();
	}

	bool AddAmmo( CBaseEntity@ pOther )
	{
		return CommonAddAmmo( pOther, MAX_CLIP, (INS2BASE::ShouldUseCustomAmmo) ? MAX_CARRY : INS2BASE::DF_MAX_CARRY_556, (INS2BASE::ShouldUseCustomAmmo) ? AMMO_TYPE : INS2BASE::DF_AMMO_556 );
	}
}

string GetAmmoName()
{
	return "ammo_ins2m60";
}*/

string GetName()
{
	return "weapon_ins2m60";
}

void Register()
{
	g_CustomEntityFuncs.RegisterCustomEntity( "INS2_M60::weapon_ins2m60", GetName() ); // Register the weapon entity
	//g_CustomEntityFuncs.RegisterCustomEntity( "INS2_M60::M60_MAG", GetAmmoName() ); // Register the ammo entity
	//g_ItemRegistry.RegisterWeapon( GetName(), SPR_CAT, (INS2BASE::ShouldUseCustomAmmo) ? AMMO_TYPE : INS2BASE::DF_AMMO_556, "", GetAmmoName() ); // Register the weapon
	g_ItemRegistry.RegisterWeapon( GetName(), SPR_CAT, "556", "", "ammo_556", "" ); // Register the weapon
}

}