// weapon_knife Version 1.2
// Custom knife weapon from Opposing Force- created using weapon_hlcrowbar and weapon_csknife from the Counter Strike Weapons Pack by KernCore
// Usage: Primary attack - Normal operation similar to crowbar
// 		  Secondary attack - Stab, does 3.5x the damage as primary but much slower. It can be delayed to time stabs
//		  Tertiary attack - Throws knife
enum knife_e
{
	KNIFE_IDLE = 0,
	KNIFE_DRAW,
	KNIFE_HOLSTER,
	KNIFE_ATTACK1,
	KNIFE_ATTACK1MISS,
	KNIFE_ATTACK2,
	KNIFE_ATTACK2HIT,
	KNIFE_ATTACK3,
	KNIFE_ATTACK3HIT,
	KNIFE_IDLE2,
	KNIFE_IDLE3,
	KNIFE_CHARGE,
	KNIFE_STAB
};

const array<string> STR_MDLS =
{
	"models/opfor/v_knife.mdl",
	"models/opfor/w_knife.mdl",
	"models/opfor/p_knife.mdl",
	"sprites/hl_weapons/weapon_knife.spr"
};

const array<string> STR_SNDS =
{
	"weapons/knife1.wav",
	"weapons/knife2.wav",
	"weapons/knife3.wav",
	"weapons/knife3.wav",
	"weapons/knife_hit_wall1.wav",
	"weapons/knife_hit_wall2.wav",
	//"weapons/hit1.wav",
	//"weapons/hit2.wav",
	//"weapons/hit3.wav",
	"weapons/knife_hit_flesh1.wav",
	"weapons/knife_hit_flesh2.wav",
	"weapons/cbar_miss1.wav",
	"weapons/cbe/cbe_idle1.wav",
	"weapons/cbe/cbe_hit1.wav",
	"weapons/cbe/cbe_hit2.wav",
	"weapons/cbe/cbe_hitbod1.wav",
	"weapons/cbe/cbe_hitbod2.wav",
	"weapons/cbe/cbe_hitbod3.wav",
	"weapons/cbe/cbe_miss1.wav",
	"weapons/cbe/cbe_miss2.wav",
	"weapons/cbe/cbe_off.wav",
	"weapons/cbe/cbe_on.wav"
};

#include "../base"

class weapon_ofknife : ScriptBasePlayerWeaponEntity
{
	private float m_flBigSwingStart;
	private float m_flRechargeTime;
	private int m_iSwingMode = 0;
	private bool isPullingBack;
	int m_iSwing;
	TraceResult m_trHit;

	private CBasePlayer@ m_pPlayer
	{
		get const 	{ return cast<CBasePlayer@>( self.m_hPlayer.GetEntity() ); }
		set       	{ self.m_hPlayer = EHandle( @value ); }
	}

	void Spawn()
	{
		self.Precache();
		g_EntityFuncs.SetModel( self, self.GetW_Model( "models/opfor/w_knife.mdl" ) );
		self.m_iClip			= -1;
		self.m_flCustomDmg		= self.pev.dmg;
		self.m_iDefaultAmmo		= 1;

		self.FallInit();// get ready to fall down.
	}

	void Precache()
	{
		self.PrecacheCustomModels();

		for( uint i = 0; i < STR_MDLS.length(); i++ )
			g_Game.PrecacheModel( STR_MDLS[i] );
		
		g_Game.PrecacheGeneric( "sprites/hl_weapons/weapon_knife.spr" );
		g_Game.PrecacheGeneric( "sprites/hl_weapons/weapon_ofknife.txt" );

		for( uint i = 0; i < STR_SNDS.length(); i++ )
		g_SoundSystem.PrecacheSound( STR_SNDS[i] );
		//g_Game.PrecacheGeneric( STR_SNDS[i] );

	}

	bool GetItemInfo( ItemInfo& out info )
	{
		info.iMaxAmmo1 	= 1;
		info.iAmmo1Drop	= 1;
		info.iMaxAmmo2 	= -1;
		info.iAmmo2Drop	= -1;
		info.iMaxClip 	= WEAPON_NOCLIP;
		info.iSlot  	= 0;
		info.iPosition 	= 7;
		info.iId     	= g_ItemRegistry.GetIdForName( self.pev.classname );
		//info.iFlags 	= 0;
		info.iFlags	= ITEM_FLAG_SELECTONEMPTY | ITEM_FLAG_NOAUTOSWITCHEMPTY;
		info.iWeight 	= 0;

		return true;
	}

	bool AddToPlayer( CBasePlayer@ pPlayer )
	{
		if( !BaseClass.AddToPlayer( pPlayer ) )
			return false;

		SetThink( null );

		NetworkMessage weapon( MSG_ONE, NetworkMessages::WeapPickup, pPlayer.edict() );
			weapon.WriteLong( g_ItemRegistry.GetIdForName( self.pev.classname ) );
		weapon.End();

		return true;
	}

	float WeaponTimeBase()
	{
		return g_Engine.time;
	}

	bool CanDeploy()
	{
		return true;
	}

	bool Deploy()
	{
		return self.DefaultDeploy( self.GetV_Model( "models/opfor/v_knife.mdl" ), self.GetP_Model( "models/opfor/p_knife.mdl" ), KNIFE_DRAW, "crowbar" );
	}

	void Holster( int skipLocal = 0 )
	{
		m_iSwing = 0;
		m_pPlayer.pev.viewmodel = string_t();
		SetThink( null );

		self.m_fInReload = false;
		BaseClass.Holster( skipLocal );
	}

	void WeaponIdle()
	{
		self.Reload();

		if( self.m_flTimeWeaponIdle > g_Engine.time )
			return;

		if( m_iSwingMode > 0 )
		{
			if( m_iSwingMode == 1 )
			{
				HeavySmack();
				m_iSwingMode = 2;
				m_flBigSwingStart = 0;
				isPullingBack = false;
			}
			else
				m_iSwingMode = 0;
		}

		if( m_iSwingMode == 0 )
		{
			m_pPlayer.m_szAnimExtension = "crowbar";
			switch( Math.RandomLong( 0, 2 ) )
			{
				case 0:
					self.SendWeaponAnim( KNIFE_IDLE, 0, 0 );
					self.m_flTimeWeaponIdle = g_Engine.time + 2.69f;
					break;
				case 1:
					self.SendWeaponAnim( KNIFE_IDLE2, 0, 0 );
					self.m_flTimeWeaponIdle = g_Engine.time + 5.33f;
					break;
				case 2:
					self.SendWeaponAnim( KNIFE_IDLE3, 0, 0 );
					self.m_flTimeWeaponIdle = g_Engine.time + 5.33f;
					break;
			}
		}
	}
	
	void PrimaryAttack()
	{
		if( !Swing( 1 ) )
		{
			SetThink( ThinkFunction( this.SwingAgain ) );
			self.pev.nextthink = g_Engine.time + 0.1;
		}
	}

	bool Swing( int fFirst )
	{
		bool fDidHit = false;

		TraceResult tr;

		//self.Reload();

		Math.MakeVectors( m_pPlayer.pev.v_angle );
		Vector vecSrc	= m_pPlayer.GetGunPosition();
		Vector vecEnd	= vecSrc + g_Engine.v_forward * 32;

		g_Utility.TraceLine( vecSrc, vecEnd, dont_ignore_monsters, m_pPlayer.edict(), tr );

		if ( tr.flFraction >= 1.0 )
		{
			g_Utility.TraceHull( vecSrc, vecEnd, dont_ignore_monsters, head_hull, m_pPlayer.edict(), tr );
			if ( tr.flFraction < 1.0 )
			{
				// Calculate the point of intersection of the line (or hull) and the object we hit
				// This is and approximation of the "best" intersection
				CBaseEntity@ pHit = g_EntityFuncs.Instance( tr.pHit );
				if ( pHit is null || pHit.IsBSPModel() )
					g_Utility.FindHullIntersection( vecSrc, tr, tr, VEC_DUCK_HULL_MIN, VEC_DUCK_HULL_MAX, m_pPlayer.edict() );
				vecEnd = tr.vecEndPos;	// This is the point on the actual surface (the hull could have hit space)
			}
		}

		if ( tr.flFraction >= 1.0 )
		{
			if( fFirst != 0 )
			{
				// miss
				switch( ( m_iSwing++ ) % 3 )
				{
				case 0:
					self.SendWeaponAnim( KNIFE_ATTACK1MISS ); break;
				case 1:
					self.SendWeaponAnim( KNIFE_ATTACK2 ); break;
				case 2:
					self.SendWeaponAnim( KNIFE_ATTACK3 ); break;
				}
				self.m_flNextPrimaryAttack = g_Engine.time + 0.5;
				// play wiff or swish sound
				g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, "weapons/knife3.wav", 1, ATTN_NORM, 0, 94 + Math.RandomLong( 0,0xF ) );

				// player "shoot" animation
				m_pPlayer.SetAnimation( PLAYER_ATTACK1 ); 
			}
		}
		else
		{
			// hit
			fDidHit = true;
			
			CBaseEntity@ pEntity = g_EntityFuncs.Instance( tr.pHit );

			switch( ( ( m_iSwing++ ) % 2 ) + 1 )
			{
			case 0:
				self.SendWeaponAnim( KNIFE_ATTACK1 ); break;
			case 1:
				self.SendWeaponAnim( KNIFE_ATTACK2HIT ); break;
			case 2:
				self.SendWeaponAnim( KNIFE_ATTACK3HIT ); break;
			}

			// player "shoot" animation
			m_pPlayer.SetAnimation( PLAYER_ATTACK1 ); 

			// AdamR: Custom damage option
			float flDamage = 40;
			if ( self.m_flCustomDmg > 0 )
				flDamage = self.m_flCustomDmg;
			// AdamR: End

			g_WeaponFuncs.ClearMultiDamage();
			if ( self.m_flNextPrimaryAttack + 1 < g_Engine.time )
			{
				// first swing does full damage
				pEntity.TraceAttack( m_pPlayer.pev, flDamage, g_Engine.v_forward, tr, DMG_SLASH | DMG_NEVERGIB );  
			}
			else
			{
				// subsequent swings do 50% (Changed -Sniper) (Half)
				pEntity.TraceAttack( m_pPlayer.pev, flDamage, g_Engine.v_forward, tr, DMG_SLASH | DMG_NEVERGIB );  
			}	
			g_WeaponFuncs.ApplyMultiDamage( m_pPlayer.pev, m_pPlayer.pev );

			//m_flNextPrimaryAttack = gpGlobals->time + 0.30; //0.25

			// play thwack, smack, or dong sound
			float flVol = 1.0;
			bool fHitWorld = true;

			if( pEntity !is null )
			{
				self.m_flNextPrimaryAttack = g_Engine.time + 0.25; //0.25

				if( pEntity.Classify() != CLASS_NONE && pEntity.Classify() != CLASS_MACHINE && pEntity.BloodColor() != DONT_BLEED )
				{
	// aone
					if( pEntity.IsPlayer() )		// lets pull them
					{
						pEntity.pev.velocity = pEntity.pev.velocity + ( self.pev.origin - pEntity.pev.origin ).Normalize() * 120;
					}
	// end aone
					// play thwack or smack sound
					switch( Math.RandomLong( 1, 2 ) )
					{
					case 1:
						g_SoundSystem.EmitSound( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_flesh1.wav", 1, ATTN_NORM ); break;
					case 2:
						g_SoundSystem.EmitSound( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_flesh2.wav", 1, ATTN_NORM ); break;
					}
					m_pPlayer.m_iWeaponVolume = 128; 
					if( !pEntity.IsAlive() )
						return true;
					else
						flVol = 0.1;

					fHitWorld = false;
				}
			}

			// play texture hit sound
			// UNDONE: Calculate the correct point of intersection when we hit with the hull instead of the line

			if( fHitWorld == true )
			{
				float fvolbar = g_SoundSystem.PlayHitSound( tr, vecSrc, vecSrc + ( vecEnd - vecSrc ) * 2, BULLET_PLAYER_CROWBAR );
				
				self.m_flNextPrimaryAttack = g_Engine.time + 0.25; //0.25
				
				// override the volume here, cause we don't play texture sounds in multiplayer, 
				// and fvolbar is going to be 0 from the above call.

				fvolbar = 1;

				// also play knife strike
				switch( Math.RandomLong( 0, 1 ) )
				{
				case 0:
					g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_wall1.wav", fvolbar, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); 
					break;
				case 1:
					g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_wall2.wav", fvolbar, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); 
					break;
				}
			}

			// delay the decal a bit
			m_trHit = tr;
			SetThink( ThinkFunction( this.Smack ) );
			self.pev.nextthink = g_Engine.time + 0.2;

			m_pPlayer.m_iWeaponVolume = int( flVol * 512 ); 
		}
		return fDidHit;
	}

	void SecondaryAttack()
	{
		if( m_iSwingMode != 1 )
		{
			self.SendWeaponAnim( KNIFE_CHARGE, 0, 0 );
			m_flBigSwingStart = g_Engine.time;
			self.m_flTimeWeaponIdle = self.m_flNextSecondaryAttack = self.m_flNextPrimaryAttack = WeaponTimeBase() + 0.7;
			m_iSwingMode = 1;
			isPullingBack = true;
		}
		if( isPullingBack == true && self.m_flTimeWeaponIdle <= g_Engine.time )
		{
			// Manually set wrench windup loop animation
			m_pPlayer.m_Activity = ACT_RELOAD;
			m_pPlayer.pev.frame = 0;
			m_pPlayer.pev.sequence = 26;
			m_pPlayer.ResetSequenceInfo();
			self.m_flNextSecondaryAttack = g_Engine.time + 2.0f;
		}

		m_iSwingMode = 1;
	}
	
	void Smack()
	{
		g_WeaponFuncs.DecalGunshot( m_trHit, BULLET_PLAYER_CROWBAR );
	}

	void SwingAgain()
	{
		Swing( 0 );
	}
	// My humble thanks to KernCore for the secondary attack functions from weapon_csknife code- used in the CS weapons pack :D
	bool HeavySmack()
	{
		//self.Reload();

		bool fDidHit = false;

		TraceResult tr;
		Math.MakeVectors( m_pPlayer.pev.v_angle );
		Vector vecSrc	= m_pPlayer.GetGunPosition();
		Vector vecEnd	= vecSrc + g_Engine.v_forward * 35;

		g_Utility.TraceLine( vecSrc, vecEnd, dont_ignore_monsters, m_pPlayer.edict(), tr );
		if( tr.flFraction >= 1.0 )
		{
			g_Utility.TraceHull( vecSrc, vecEnd, dont_ignore_monsters, head_hull, m_pPlayer.edict(), tr );
			if( tr.flFraction < 1.0 )
			{
				EHandle hHit = g_EntityFuncs.Instance( tr.pHit );
				if( hHit.GetEntity() is null || hHit.GetEntity().IsBSPModel() )
					g_Utility.FindHullIntersection( vecSrc, tr, tr, VEC_DUCK_HULL_MIN, VEC_DUCK_HULL_MAX, m_pPlayer.edict() );

				vecEnd = tr.vecEndPos;
			}
		}
		g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife1.wav", 1, ATTN_NORM, 0, 94 + Math.RandomLong( 0,0xF ) );
		m_pPlayer.m_szAnimExtension = "wrench";
		if( tr.flFraction >= 1.0 )
		{
			self.SendWeaponAnim( KNIFE_STAB, 0, 0 );
			self.m_flTimeWeaponIdle = self.m_flNextSecondaryAttack = self.m_flNextPrimaryAttack = g_Engine.time + 0.35;
			//Miss
			m_pPlayer.SetAnimation( PLAYER_ATTACK1 );
		}
		else
		{
			//Hit
			fDidHit = true;
			self.SendWeaponAnim( KNIFE_STAB, 0, 0 );
			m_pPlayer.SetAnimation( PLAYER_ATTACK1 );
			EHandle hEntity = g_EntityFuncs.Instance( tr.pHit );

			if( hEntity.GetEntity() !is null )
			{
				g_WeaponFuncs.ClearMultiDamage();
				float flDamage = 160;
				if( self.m_flNextSecondaryAttack + 1 < g_Engine.time )
				{
					hEntity.GetEntity().TraceAttack( m_pPlayer.pev, flDamage, g_Engine.v_forward, tr, DMG_SLASH | DMG_ALWAYSGIB );
				}
				else
				{
					hEntity.GetEntity().TraceAttack( m_pPlayer.pev, flDamage, g_Engine.v_forward, tr, DMG_SLASH | DMG_ALWAYSGIB );
				}
				g_WeaponFuncs.ApplyMultiDamage( m_pPlayer.pev, m_pPlayer.pev );
			}

			// play thwack, smack, or dong sound
			float flVol = 1.0;
			bool fHitWorld = true;
			if( hEntity.GetEntity() !is null )
			{
				self.m_flTimeWeaponIdle = self.m_flNextSecondaryAttack = self.m_flNextPrimaryAttack = g_Engine.time + 0.3;
				if( hEntity.GetEntity().Classify() != CLASS_NONE && hEntity.GetEntity().Classify() != CLASS_MACHINE && hEntity.GetEntity().BloodColor() != DONT_BLEED )
				{
					if( hEntity.GetEntity().IsPlayer() ) // lets pull them
					{
						hEntity.GetEntity().pev.velocity = hEntity.GetEntity().pev.velocity + ( self.pev.origin - hEntity.GetEntity().pev.origin ).Normalize() * 120;
					}

					// play thwack or smack sound
					switch( Math.RandomLong( 0, 2 ) )
					{
						case 0:
							//g_SoundSystem.EmitSound( m_pPlayer.edict(), CHAN_AUTO, "weapons/hit1.wav", 1, ATTN_NORM );
							g_SoundSystem.EmitSound( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_flesh1.wav", 1, ATTN_NORM );
							break;
						case 1:
							//g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/hit2.wav", 1, ATTN_NORM ); 
							g_SoundSystem.EmitSound( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_flesh2.wav", 1, ATTN_NORM );
							break;
						case 2:
							//g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/hit3.wav", 1, ATTN_NORM ); 
							g_SoundSystem.EmitSound( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_flesh1.wav", 1, ATTN_NORM );
							break;
					}

					m_pPlayer.m_iWeaponVolume = 128;
					if( !hEntity.GetEntity().IsAlive() )
						return true;
					else
						flVol = 0.1;

					fHitWorld = false;
				}
			}

			if( fHitWorld == true )
			{
				float fvolbar = g_SoundSystem.PlayHitSound( tr, vecSrc, vecSrc + (vecEnd - vecSrc) * 2, BULLET_PLAYER_CROWBAR );

				// override the volume here, cause we don't play texture sounds in multiplayer, 
				// and fvolbar is going to be 0 from the above call.
				fvolbar = 1;
				// also play crowbar strike
				switch( Math.RandomLong( 0, 1 ) )
				{
					case 0:
						g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_wall1.wav", fvolbar, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); 
						break;
					case 1:
						g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_AUTO, "weapons/knife_hit_wall2.wav", fvolbar, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); 
						break;
				}
			}
		}

		g_WeaponFuncs.DecalGunshot( g_Utility.GetGlobalTrace(), BULLET_PLAYER_CROWBAR );
		return fDidHit;
	}

	void TertiaryAttack()
	{
		if ( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 0 )
		{
			return;
		}

		Vector vecSrc = m_pPlayer.GetGunPosition();
		self.SendWeaponAnim( KNIFE_ATTACK1MISS );
		m_pPlayer.SetAnimation( PLAYER_ATTACK1 );
		g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, "weapons/knife3.wav", 1, 0.8, 0, 150 );
		bool isAdmin = g_PlayerFuncs.AdminLevel(m_pPlayer) >= ADMIN_YES;

		Math.MakeVectors( m_pPlayer.pev.v_angle );

		CBaseEntity@ pTKnife = g_EntityFuncs.Create( "knife_throw", vecSrc, m_pPlayer.pev.v_angle, false, m_pPlayer.edict() );
		if( pTKnife !is null )
		{
			if( pev.waterlevel != 0 )
			{
				pTKnife.pev.velocity = g_Engine.v_forward * 512;
			}
			else
			{
				pTKnife.pev.velocity = g_Engine.v_forward * 1024;
			}
			pTKnife.pev.angles = Math.VecToAngles( pTKnife.pev.velocity );
			//pTKnife.pev.avelocity.z = 5;

			//knife_throw@ pKnife = cast<knife_throw@>(CastToScriptClass(pTKnife));
			//pKnife.SetThink( ThinkFunction( pKnife.Think ) );
			//pKnife.pev.nextthink = g_Engine.time + 0.1;

			if( !isAdmin )
			{
				self.Reload();
				m_flRechargeTime = g_Engine.time + 5.0;
				self.m_flNextPrimaryAttack = g_Engine.time + 0.4;
				self.m_flNextSecondaryAttack = g_Engine.time + 0.4;
				self.m_flNextTertiaryAttack = g_Engine.time + 0.4;
				self.m_flTimeWeaponIdle = g_Engine.time + 1.0;

				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) - 1 );
			}
			else
			{
				self.Reload();
				m_flRechargeTime = g_Engine.time + 5.0;
				self.m_flNextPrimaryAttack = g_Engine.time + 0.4;
				self.m_flNextSecondaryAttack = g_Engine.time + 0.4;
				self.m_flNextTertiaryAttack = g_Engine.time + 0.4;
				self.m_flTimeWeaponIdle = g_Engine.time + 1.0;

				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) - 1 );
			}
		}
	}

	void Reload()
	{
		if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 1 )
			return;

		if( m_pPlayer !is null )
		{
			while( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 0 && m_flRechargeTime < g_Engine.time )
			{
				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, 1 );
				m_flRechargeTime += 0.2;
			}
		}
	}

	/*void ItemPreFrame()
	{
		if ( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 0 )
		{
			self.Reload();
			self.pev.nextthink = g_Engine.time + 0.1;
		}
	}

	void ItemPostFrame()
	{
		if ( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 0 )
		{
			self.Reload();
			self.pev.nextthink = g_Engine.time + 0.1;
		}

		BaseClass.ItemPostFrame();
	}

	void InactiveItemPostFrame()
	{
		if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 0 )
		{
			self.Destroy();
			self.pev.nextthink = g_Engine.time + 0.1;
		}
	}*/

	void ItemPostFrame()
	{
		if ( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) == 0 )
		{
			self.Reload();
			self.pev.nextthink = g_Engine.time + 0.1;
		}

		BaseClass.ItemPostFrame();
	}

	void DestroyThink()
	{
		g_EntityFuncs.Remove( self );
	}

	void FadeOut()
	{
		pev.nextthink = g_Engine.time + 0.1;

		if( pev.rendermode == kRenderNormal )
		{
			pev.renderamt = 255;
			pev.rendermode = kRenderTransTexture;
		}

		if( pev.renderamt > 7 )
		{
			pev.renderamt -= 7;
		}
		else
		{
			pev.renderamt = 0;
			pev.nextthink = g_Engine.time + 0.1f;
			SetThink( ThinkFunction( this.DestroyThink ) );
			return;
		}
	}

	bool CanHaveDuplicates()
	{
		return true;
	}
}

class knife_throw : ScriptBaseEntity
{
	private string MODEL = STR_MDLS[2];

	private array<string> pHitSounds =
	{
		"weapons/knife_hit_flesh1.wav",
		"weapons/knife_hit_flesh2.wav"
	};

	private array<string> pHitMissSounds =
	{
		"weapons/knife_hit_wall1.wav",
		"weapons/knife_hit_wall2.wav"
	};

	void Spawn()
	{
		self.pev.movetype = MOVETYPE_BOUNCE;
		self.pev.solid = SOLID_BBOX;
		self.pev.gravity = 0.2;

		g_EntityFuncs.SetModel( self, "models/opfor/w_knife.mdl" );

		self.pev.animtime = g_Engine.time;
		self.pev.framerate = 1.0f;
		self.pev.frame = 0.0f;
		self.pev.avelocity = Vector( 1200, 0, 0 );

		g_EntityFuncs.SetOrigin( self, self.pev.origin );
		//g_EntityFuncs.SetSize( self.pev, Vector(-3.0, -3.0, -3.0), Vector(3.0, 3.0, 3.0) );
	}

	void KnifeCasting( const Vector& in origin, const Vector& in velocity, int iModel, bool i_isRevolver, int quantity ) // drop magazines
	{
		int lifetime = 20;
		int i = 0;

		if( i_isRevolver == true )
		{
			while( i < quantity )
			{
				NetworkMessage buldrop( MSG_BROADCAST, NetworkMessages::SVC_TEMPENTITY );
					buldrop.WriteByte( TE_MODEL );
					buldrop.WriteCoord( origin.x );
					buldrop.WriteCoord( origin.y );
					buldrop.WriteCoord( origin.z );
					buldrop.WriteCoord( velocity.x + Math.RandomLong( -20, 20 ) ); // velocity
					buldrop.WriteCoord( velocity.y + Math.RandomLong( -20, 20 ) ); // velocity
					buldrop.WriteCoord( velocity.z + Math.RandomLong( -20, 20 ) ); // velocity
					buldrop.WriteAngle( Math.RandomFloat( 0, 180 ) ); // yaw
					buldrop.WriteShort( iModel ); // model
					buldrop.WriteByte( 1 ); // bouncesound
					buldrop.WriteByte( int( lifetime ) ); // decay time
				buldrop.End();
				i++;
			}
		}
		else
		{
			/*NetworkMessage magdrop( MSG_BROADCAST, NetworkMessages::SVC_TEMPENTITY, null );
				magdrop.WriteByte( TE_BREAKMODEL );
				magdrop.WriteCoord( origin.x );
				magdrop.WriteCoord( origin.y );
				magdrop.WriteCoord( origin.z );
				magdrop.WriteCoord( 0 ); //size
				magdrop.WriteCoord( 0 ); //size
				magdrop.WriteCoord( 0 ); //size
				magdrop.WriteCoord( velocity.x );
				magdrop.WriteCoord( velocity.y );
				magdrop.WriteCoord( velocity.z );
				magdrop.WriteByte( 2 ); //speedNoise
				magdrop.WriteShort( iModel );
				magdrop.WriteByte( 1 ); //count
				magdrop.WriteByte( lifetime ); //time
				magdrop.WriteByte( 2 ); //flags
			magdrop.End();*/

			NetworkMessage buldrop( MSG_BROADCAST, NetworkMessages::SVC_TEMPENTITY );
				buldrop.WriteByte( TE_MODEL );
				buldrop.WriteCoord( origin.x );
				buldrop.WriteCoord( origin.y );
				buldrop.WriteCoord( origin.z );
				buldrop.WriteCoord( velocity.x ); // velocity
				buldrop.WriteCoord( velocity.y ); // velocity
				buldrop.WriteCoord( velocity.z ); // velocity
				buldrop.WriteAngle( 0 ); // yaw
				buldrop.WriteShort( iModel ); // model
				buldrop.WriteByte( 1 ); // bouncesound
				buldrop.WriteByte( int( lifetime ) ); // decay time
			buldrop.End();
		}
	}

	void Think( void )
	{
		pev.nextthink = g_Engine.time + 0.1;

		if( pev.waterlevel != 0 )
			pev.velocity = pev.velocity * 0.5;

		Vector vecAngle;
		vecAngle = Math.VecToAngles( pev.velocity ); // Angle the knife depending on the velocity
		pev.angles.x = vecAngle.x;
		pev.angles.y = vecAngle.y;
		//pev.angles.z = vecAngle.z;
		pev.angles.z += 2.0f;
	}

	void Touch( CBaseEntity@ pOther )
	{
		SetThink( null );
		SetTouch( null );

		if( pOther.pev.takedamage > DAMAGE_NO )
		{
			TraceResult tr = g_Utility.GetGlobalTrace( );

			g_WeaponFuncs.ClearMultiDamage();
			pOther.TraceAttack( pev.owner.vars, 175, g_Engine.v_forward, tr, DMG_SNIPER | DMG_NEVERGIB );  
			g_WeaponFuncs.ApplyMultiDamage( self.pev, pev.owner.vars );

			pev.velocity = g_vecZero;

			g_SoundSystem.EmitSoundDyn( self.edict(), CHAN_BODY, pHitSounds[Math.RandomLong(0, pHitSounds.length()-1)], 1.0f, ATTN_NORM, 0, PITCH_NORM );

			/*CBaseEntity @pEntity = g_EntityFuncs.CreateEntity( "weapon_ofknife", null, false );
			if( pEntity !is null )
			{
				g_EntityFuncs.DispatchSpawn( pEntity.edict() );

				g_EntityFuncs.SetModel( pEntity, "models/opfor/w_knife.mdl" );
				g_EntityFuncs.SetOrigin( pEntity, self.pev.origin );
				@pEntity.pev.owner = pev.owner;
				@pEntity.pev.aiment = @self.pev.owner;
				pEntity.pev.movetype = MOVETYPE_FOLLOW;
				pEntity.pev.spawnflags = 7168;

				pEntity.pev.angles.x = pev.angles.x;
				pEntity.pev.angles.y = pev.angles.y;
				pEntity.pev.angles.z = pev.angles.z;

				//pEntity.pev.velocity = pev.velocity + g_Engine.v_forward * Math.RandomFloat(-200, -400) + g_Engine.v_up * Math.RandomFloat(100, 200) + g_Engine.v_right * Math.RandomFloat(-100, 100);
				pEntity.pev.avelocity = Vector( 1200, 1200, 0 );
			}*/

			KnifeCasting( pev.origin, pev.velocity + (g_Engine.v_forward * Math.RandomFloat(-100, -200)) + (g_Engine.v_up * Math.RandomFloat(100, 200)) + (g_Engine.v_right * Math.RandomFloat(-100, 100)), iKnifeModel, false, 0 );

		}
		else
		{
			g_SoundSystem.EmitSoundDyn( self.edict(), CHAN_BODY, pHitMissSounds[Math.RandomLong(0, pHitMissSounds.length()-1)], 1.0f, ATTN_NORM, 0, PITCH_NORM );

			if( pOther.pev.ClassNameIs( "worldspawn" ) )
			{
				// if what we hit is static architecture, can stay around for a while.
				Vector vecDir = pev.velocity.Normalize();
				pev.origin = pev.origin - vecDir * 1;
				pev.solid = SOLID_NOT;
				pev.movetype = MOVETYPE_NONE;
				pev.velocity = g_vecZero;
				pev.avelocity.z = 0;
			}

			if( g_EngineFuncs.PointContents(self.pev.origin) != CONTENTS_WATER )
				g_Utility.Sparks( pev.origin );

			/*CBaseEntity @pEntity2 = g_EntityFuncs.CreateEntity( "weapon_ofknife", null, false );
			if( pEntity2 !is null )
			{
				g_EntityFuncs.DispatchSpawn( pEntity2.edict() );

				g_EntityFuncs.SetModel( pEntity2, "models/opfor/w_knife.mdl" );
				g_EntityFuncs.SetOrigin( pEntity2, self.pev.origin );
				pEntity2.pev.movetype = MOVETYPE_NONE;
				pEntity2.pev.spawnflags = 7424;

				pEntity2.pev.rendermode = 0.0;
				pEntity2.pev.renderfx = kRenderFxGlowShell;
				pEntity2.pev.renderamt = 1.0;
				pEntity2.pev.rendercolor = Vector(150, 150, 150);

				pEntity2.pev.angles.x = pev.angles.x;
				pEntity2.pev.angles.y = pev.angles.y;
				pEntity2.pev.angles.z = pev.angles.z;
			}*/

			KnifeCasting( pev.origin, pev.velocity + (g_Engine.v_forward * Math.RandomFloat(-100, -200)) + (g_Engine.v_up * Math.RandomFloat(100, 200)) + (g_Engine.v_right * Math.RandomFloat(-100, 100)), iKnifeModel, false, 0 );
			
		}

		g_EntityFuncs.Remove( self );
		pev.nextthink = g_Engine.time + 0.1;
	}
}

void RegisterKnife()
{
	g_CustomEntityFuncs.RegisterCustomEntity( "weapon_ofknife", "weapon_ofknife" );
	g_CustomEntityFuncs.RegisterCustomEntity( "knife_throw", "knife_throw" );
	g_ItemRegistry.RegisterWeapon( "weapon_ofknife", "hl_weapons", "weapon_ofknife", "", "weapon_ofknife" );
}
// Credit to KernCore for secondary attack functions