/* 
* The original Half-Life version of the Hornet Gun
* Modified for the Crack-Life Sven Co-op conversion
* Original Crack-Life mod by: Siemka321
* Sven Co-op Re-conversion: Rafael "R4to0" Alves
* Modified, again, to resemble the Alien Grunt Hivehand weapon
* By: Sidewinder
* https://steamcommunity.com/id/tehsnek/
* Enjoy!
*/

// Hornet projectile
#include "proj_hivehornet"

namespace HIVEHAND
{

enum hgun_e
{
	HGUN_IDLE1 = 0,
	HGUN_DOWN,
	HGUN_UP,
	HGUN_SHOOT
};

// Models
const string g_PeeMdl		=  "models/hivehand/p_hivehand.mdl";
const string g_VeeMdl		=  "models/hivehand/v_hivehand.mdl";
const string g_WeeMdl		=  "models/hivehand/w_hivehand.mdl";

// Sounds
const string g_Fire1Snd		= "agrunt/ag_fire1.wav";
const string g_Fire2Snd		= "agrunt/ag_fire2.wav";
const string g_Fire3Snd		= "agrunt/ag_fire3.wav";

// Weapon Info
const uint g_DefGivePri		= 8;
const uint g_MaxAmmoPri		= 8;
const uint g_Weight		= 10;
const string g_WeaponName	= "weapon_hivehand";

// Weapon HUD
uint g_Slot			= 8;
uint g_Position			= 2;

// Fire rate delay
const float g_FRDelay = 0.2f;
const float g_RLDelay = 1.0f;

class weapon_hivehand : ScriptBasePlayerWeaponEntity
{
	int m_iFirePhase;
	float m_flRechargeTime;
	float m_flTimeWeaponIdle;
	private int m_iAgruntMuzzleFlash;

	private CBasePlayer@ m_pPlayer
	{
		get const 	{ return cast<CBasePlayer@>( self.m_hPlayer.GetEntity() ); }
		set       	{ self.m_hPlayer = EHandle( @value ); }
	}

	void Spawn()
	{
		Precache();
		g_EntityFuncs.SetModel( self, g_WeeMdl );

		self.m_iDefaultAmmo = g_DefGivePri;

		m_iFirePhase = 0;

		self.FallInit();
	}

	void Precache()
	{
		// Models
		self.PrecacheCustomModels();
		g_Game.PrecacheModel( "models/sentry.mdl" );
		g_Game.PrecacheModel( "models/hivehand/p_hivehand.mdl" );
		g_Game.PrecacheModel( "models/hivehand/v_hivehand.mdl" );
		g_Game.PrecacheModel( "models/hivehand/w_hivehand.mdl" );
		g_Game.PrecacheModel( "models/hivehand/w_hivehandT.mdl" );
		m_iAgruntMuzzleFlash = g_Game.PrecacheModel( "sprites/muz4.spr" );


		// Sounds
		g_SoundSystem.PrecacheSound( "agrunt/ag_fire1.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_fire2.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_fire3.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_die1.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_die2.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_die3.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_die4.wav" );
		g_SoundSystem.PrecacheSound( "agrunt/ag_die5.wav" );

		// Precache hornet projectile
		g_Game.PrecacheOther( "hivehornet" );
	}

	bool RemoveSingleItem(CBasePlayer@ pTarget, string targetWeapon)
	{
		//instantly fail if attempting to remove the afb's entmover
		if(targetWeapon == "weapon_entmover") return false;
		
		CBasePlayerItem@ pItem;
		CBasePlayerWeapon@ pWeapon;
		for(uint j = 0; j < MAX_ITEM_TYPES; j++)
		{
			@pItem = pTarget.m_rgpPlayerItems(j);
			while(pItem !is null)
			{
				@pWeapon = pItem.GetWeaponPtr();
				
				if(pWeapon.GetClassname() == targetWeapon)
				{
					pTarget.RemovePlayerItem(pItem);
					return true;
				}
				
				@pItem = cast<CBasePlayerItem@>(pItem.m_hNextItem.GetEntity());
			}
		}
		
		return false;
	}

	bool AddToPlayer( CBasePlayer@ pPlayer )
	{
		if( BaseClass.AddToPlayer( pPlayer ) == true )
		{
			@m_pPlayer = pPlayer;

			g_SoundSystem.EmitSoundDyn( pPlayer.edict(), CHAN_WEAPON, "will/null.wav", 1.0, 0.3, 0, PITCH_NORM );

			NetworkMessage hivehand( MSG_ONE, NetworkMessages::WeapPickup, pPlayer.edict() );
			hivehand.WriteLong( g_ItemRegistry.GetIdForName( self.pev.classname ) );
			hivehand.End();
			return true;
		}

		return false;
	}

	bool GetItemInfo( ItemInfo& out info )
	{
		info.iMaxAmmo1 	= g_MaxAmmoPri;
		info.iMaxAmmo2	= -1;
		info.iMaxClip 	= -1;
		info.iSlot 	= g_Slot;
		info.iPosition 	= g_Position;
		info.iFlags	= ITEM_FLAG_SELECTONEMPTY | ITEM_FLAG_NOAUTOSWITCHEMPTY; // select even if is empty
		info.iId	= g_ItemRegistry.GetIdForName( self.pev.classname );
		info.iWeight 	= g_Weight;

		return true;
	}
	
	float WeaponTimeBase()
	{
		return g_Engine.time;
	}

	bool Deploy()
	{
		m_pPlayer.SetMaxSpeedOverride( 230 );
		return self.DefaultDeploy( g_VeeMdl, g_PeeMdl, HGUN_UP, "hive" );
	}

	void Holster( int skipLocal = 0 )
	{
		self.SendWeaponAnim( HGUN_DOWN );

		m_pPlayer.SetMaxSpeedOverride( -1 );

		if ( m_pPlayer !is null && (m_pPlayer.pev.flags & FL_FAKECLIENT) != 0 )
		{
			if ( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 0 )
				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) + 10 );
		}
		else
		{
			if ( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 0 )
				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) + 8 );
		}

		if( !m_pPlayer.IsAlive() && (m_pPlayer.pev.flags & FL_FAKECLIENT) != 0 )
		{
			RemoveSingleItem(m_pPlayer, "weapon_hivehand");
		}

		SetThink( null );
		BaseClass.Holster( skipLocal );

	}

	void PrimaryAttack()
	{
		self.Reload();

		if ( m_pPlayer !is null && (m_pPlayer.pev.flags & FL_FAKECLIENT) != 0 )
		{
			if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 2 )
				return;
		}
		else
		{
			if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 0 )
				return;
		}
		
		Vector vecSrc;
		Vector vecSrc2;
		TraceResult tr;
		Vector trace_origin;
		trace_origin = m_pPlayer.pev.origin;

		g_Utility.TraceLine( trace_origin + g_Engine.v_forward * 85, trace_origin + g_Engine.v_forward * 44, dont_ignore_monsters, null, tr );

		vecSrc = m_pPlayer.GetGunPosition() + g_Engine.v_forward * 52 + g_Engine.v_right * 8 + g_Engine.v_up * -12;
		vecSrc2 = m_pPlayer.GetGunPosition() + g_Engine.v_forward * 70 + g_Engine.v_right * 8 + g_Engine.v_up * -18;

		m_iFirePhase++;
		switch ( m_iFirePhase )
		{
		case 1:
			vecSrc = vecSrc + g_Engine.v_up * -5;
			break;
		case 2:
			vecSrc = vecSrc + g_Engine.v_up * 5;
			vecSrc = vecSrc + g_Engine.v_right * 5;
			break;
		case 3:
			vecSrc = vecSrc + g_Engine.v_right * 5;
			break;
		case 4:
			vecSrc = vecSrc + g_Engine.v_up * -5;
			vecSrc = vecSrc + g_Engine.v_right * 5;
			break;
		case 5:
			vecSrc = vecSrc + g_Engine.v_up * -5;
			break;
		case 6:
			vecSrc = vecSrc + g_Engine.v_up * -5;
			vecSrc = vecSrc + g_Engine.v_right * 5;
			break;
		case 7:
			vecSrc = vecSrc + g_Engine.v_right * -5;
			break;
		case 8:
			vecSrc = vecSrc + g_Engine.v_up * -5;
			vecSrc = vecSrc + g_Engine.v_right * -5;
			m_iFirePhase = 0;
			break;
		}

		if (tr.fAllSolid == 0 && tr.fStartSolid == 0)
		{
			pev.effects = EF_MUZZLEFLASH;

			NetworkMessage message( MSG_PVS, NetworkMessages::SVC_TEMPENTITY, vecSrc2 );
				message.WriteByte(TE_SPRITE);
				message.WriteCoord(vecSrc2.x);
				message.WriteCoord(vecSrc2.y);
				message.WriteCoord(vecSrc2.z);
				message.WriteShort(m_iAgruntMuzzleFlash);
				message.WriteByte(6);
				message.WriteByte(128);
			message.End();

			// Shoot the hornet
			CBaseEntity@ pHornet = g_EntityFuncs.Create( "hivehornet", vecSrc, m_pPlayer.pev.v_angle, false, m_pPlayer.edict() );
			pHornet.pev.velocity = g_Engine.v_forward * 325;

			m_flRechargeTime = g_Engine.time + g_RLDelay; // 0.5

			m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) - 1 );

			m_pPlayer.m_iWeaponVolume = QUIET_GUN_VOLUME;
			m_pPlayer.m_iWeaponFlash = DIM_GUN_FLASH;

			self.SendWeaponAnim( HGUN_SHOOT, 0, 0 );

			// Fire sound
			switch ( Math.RandomLong ( 0 , 2 ) )
			{
				case 0:	g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, g_Fire1Snd, 1.0, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); break;
				case 1:	g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, g_Fire2Snd, 1.0, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); break;
				case 2:	g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, g_Fire3Snd, 1.0, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); break;
			}

			// player "shoot" animation
			m_pPlayer.SetAnimation( PLAYER_ATTACK1 );

			self.m_flNextPrimaryAttack = g_Engine.time + g_FRDelay; // 0.2
			self.m_flTimeWeaponIdle = g_Engine.time + g_PlayerFuncs.SharedRandomFloat( m_pPlayer.random_seed,  10, 15 );
		}
	}
	
	void SecondaryAttack()
	{
		self.Reload();

		if ( m_pPlayer !is null && (m_pPlayer.pev.flags & FL_FAKECLIENT) != 0 )
		{
			if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 2 )
				return;
		}
		else
		{
			if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) <= 0 )
				return;
		}

		Vector vecSrc;
		Vector vecSrc2;

		TraceResult tr;
		Vector trace_origin;
		trace_origin = m_pPlayer.pev.origin;

		vecSrc = m_pPlayer.GetGunPosition() + g_Engine.v_forward * 52 + g_Engine.v_right * 8 + g_Engine.v_up * -12;
		vecSrc2 = m_pPlayer.GetGunPosition() + g_Engine.v_forward * 70 + g_Engine.v_right * 8 + g_Engine.v_up * -18;

		g_Utility.TraceLine( trace_origin + g_Engine.v_forward * 85, trace_origin + g_Engine.v_forward * 44, dont_ignore_monsters, null, tr );

		if (tr.fAllSolid == 0 && tr.fStartSolid == 0)
		{
			pev.effects = EF_MUZZLEFLASH;

			NetworkMessage message( MSG_PVS, NetworkMessages::SVC_TEMPENTITY, vecSrc2 );
				message.WriteByte(TE_SPRITE);
				message.WriteCoord(vecSrc2.x);
				message.WriteCoord(vecSrc2.y);
				message.WriteCoord(vecSrc2.z);
				message.WriteShort(m_iAgruntMuzzleFlash);
				message.WriteByte(6);
				message.WriteByte(128);
			message.End();


			CBaseEntity@ cbehivehornet = g_EntityFuncs.Create( "hivehornet", vecSrc, m_pPlayer.pev.v_angle, false, m_pPlayer.edict() );
			HIVEHORNET::hivehornet@ pHornet = cast<HIVEHORNET::hivehornet@>( CastToScriptClass( cbehivehornet ) );
			g_EntityFuncs.DispatchSpawn( pHornet.self.edict() );
			pHornet.pev.velocity = g_Engine.v_forward * 1200;
			pHornet.pev.angles = Math.VecToAngles( pHornet.pev.velocity );
			pHornet.SetThink( ThinkFunction( pHornet.StartDart ) );

			m_flRechargeTime = g_Engine.time + g_RLDelay; // 0.5

			m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) - 1 );

			m_pPlayer.m_iWeaponVolume = QUIET_GUN_VOLUME;
			m_pPlayer.m_iWeaponFlash = DIM_GUN_FLASH;

			self.SendWeaponAnim( HGUN_SHOOT, 0, 0 );

			// Fire sound
			switch ( Math.RandomLong ( 0 , 2 ) )
			{
				case 0:	g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, g_Fire1Snd, 1.0, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); break;
				case 1:	g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, g_Fire2Snd, 1.0, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); break;
				case 2:	g_SoundSystem.EmitSoundDyn( m_pPlayer.edict(), CHAN_WEAPON, g_Fire3Snd, 1.0, ATTN_NORM, 0, 98 + Math.RandomLong( 0, 3 ) ); break;
			}

			// player "shoot" animation
			m_pPlayer.SetAnimation( PLAYER_ATTACK1 );

			self.m_flNextPrimaryAttack = self.m_flNextSecondaryAttack = g_Engine.time + 0.2;
			self.m_flTimeWeaponIdle = g_Engine.time + g_PlayerFuncs.SharedRandomFloat( m_pPlayer.random_seed,  10, 15 );
		}
	}

	void Reload()
	{
		if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType )>= g_MaxAmmoPri )
		return;

		if( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType )== g_MaxAmmoPri )
		return;

		if ( m_pPlayer !is null && (m_pPlayer.pev.flags & FL_FAKECLIENT) != 0 )
		{
			while( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) < g_MaxAmmoPri && m_flRechargeTime < g_Engine.time )
			{
				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, 10 );
				m_flRechargeTime += 0.001;
			}
		}
		else
		{
			while( m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType ) < g_MaxAmmoPri && m_flRechargeTime < g_Engine.time )
			{
				m_pPlayer.m_rgAmmo( self.m_iPrimaryAmmoType, g_MaxAmmoPri );
				m_flRechargeTime += 0.001;
			}
		}
	}

	void WeaponIdle()
	{
		self.Reload();

		if( m_flTimeWeaponIdle > g_Engine.time )
			return;

		int iAnim;
		iAnim = HGUN_IDLE1;
		m_flTimeWeaponIdle = g_Engine.time + 30.0 / 16 * (2);

		self.SendWeaponAnim( iAnim );
	}
}

void Register()
{
	HIVEHORNET::Register();
	g_CustomEntityFuncs.RegisterCustomEntity( "HIVEHAND::weapon_hivehand", g_WeaponName );
	g_ItemRegistry.RegisterWeapon( g_WeaponName, "hl_weapons", "Hornet" );
}

} // End of namespace